Setting the RowStatus

If you have worked with PowerBuilder for a while, you have learned that setting the status of a row is not always a straight forward procedure.  I have created a handy utility which will simplify this process.

Row Status

Each row contains a status which determines what type of SQL statement the datawindow needs to generate when it is asked to update.  The possible enumerated values are:

• New!
• NewModified!
• NotModified!
• DataModified!

The datawindow automatically maintains the row status in the background.

SetItemStatus

There are times when you want to change the row status programmatically.  This is done with the SetItemStatus() function which contains the following arguments:

• Row
• Column
• Buffer

When setting the row status, the column argument needs to be zero.  I have never selected the Delete! buffer, if you have played around with this, let me know if there is anything special about this.

The problem is that setting the row status to a new value may result in a new unexpected value.  To get around this, Powerbuilder supplies the following table:

If a row begins with a status of NewModified! and you set the row status to NotModifed!, the actual row status changes to  New!

So in order to change the row status of a NewModified! row to NotModified!, you must set the row to DataModified!  Then you must set the row NotModifed! with a second SetItem function.

This is not exactly programmer friendly.  For the life of me, I don’t know why PowerBuilder makes us do this dance.  If  I want to set a row’s status to DataModified!, it should be a one function call, regardless of what the current status of the row is.  And I should not have to refer to this mysterious chart.

To ease this burden, I wrote the following function, and I put it in a nvo with other home built datawindow utilities.  It is overloaded with a function which assumes the Primary!buffer.

This function resides on a nvo inherited from the PFC’s n_base object.  This object supplies the constants SUCCESS and FAILURE.

of_SetRowStatus()

</pre>
//////////////////////////////////////////////////////////////////////////////
//
//   Function: of_SetRowStatus (overloaded function to include buffer)
//
//   Access: Public
//
//   Description: Sets the Rowstatus of the passed row.  It changes the rowstatus
//              of the row and datastore specified in ai_row and adw, to the
//              status specified in astatus_new.
//
//   Arguments: u_dw   adw
//            integer       ai_row
//            dwItemStatus  astatus_new
//            dwbuffer      adwbuffer
//
//   Returns:   integer
//
//////////////////////////////////////////////////////////////////////////////
//   Revision History
//
// Date      By   Description/Comments
// --------  ---  -------------------------------------------
// 05/10/06  fjs  Initial Version  (overloaded from original)
// 05/24/06  fjs  Only Primary! and Filter! buffers supported.
// 02/06/09  fjs  Fixed bug with New! going to NotModified!
//////////////////////////////////////////////////////////////////////////////

dwItemStatus lstatus_cur, lstatus_changed
integer      li_rc = SUCCESS, li_row_cnt
string       ls_msg

// validate arguments
if li_rc = SUCCESS then
   if Not IsValid(adw) then
   li_rc = FAILURE
     ls_msg = "Passed datastore is not valid"
   end if
end if

if li_rc = SUCCESS then
   if IsNull(ai_row) then
      li_rc = FAILURE
      ls_msg = "Passed row must not be null"
   end if
end if

if li_rc = SUCCESS then
   if ai_row < 1 then
      li_rc = FAILURE
      ls_msg = "Passed row must be greater than 0"
   end if
end if

if li_rc = SUCCESS then
   choose case adwbuffer
      case Primary!
         li_row_cnt = adw.RowCount()
      case Filter!
         li_row_cnt = adw.FilteredCount()
//    case Delete!  // got to test this
//       li_row_cnt = adw.DeleteCount()
      case else
         li_rc  = FAILURE
         ls_msg = "Passed adwbuffer is not known or not supported"
   end choose
end if

if li_rc = SUCCESS then
   if ai_row > li_row_cnt then
   li_rc = FAILURE
     ls_msg = "Passed row is greater than number of rows in datastore"
   end if
end if

//change the rows status
if li_rc = SUCCESS then
   lstatus_cur = adw.GetItemStatus(ai_row, 0, adwbuffer)
   choose case lstatus_cur
      case New!
         choose case astatus_new
         case New!
            li_rc = NO_ACTION
         case NewModified!, DataModified!
            adw.SetItemStatus(ai_row, 0, adwbuffer, astatus_new)
         case NotModified!
            adw.SetItemStatus(ai_row, 0, adwbuffer, DataModified!)
            adw.SetItemStatus(ai_row, 0, adwbuffer, NotModified!)
         end choose
      case NewModified!
         choose case astatus_new
            case New!
               adw.SetItemStatus(ai_row, 0, adwbuffer, NotModified!)
            case NewModified!
               li_rc = NO_ACTION
            case DataModified!
               adw.SetItemStatus(ai_row, 0, adwbuffer, astatus_new)
            case NotModified!
               adw.SetItemStatus(ai_row, 0, adwbuffer, DataModified!)
               adw.SetItemStatus(ai_row, 0, adwbuffer, NotModified!)
            end choose  
      case DataModified!
         choose case astatus_new
            case New!
               adw.SetItemStatus(ai_row, 0, adwbuffer, NotModified!)
               adw.SetItemStatus(ai_row, 0, adwbuffer, New!)  
            case NewModified!, NotModified!
               adw.SetItemStatus(ai_row, 0, adwbuffer, astatus_new)
            case DataModified!
               li_rc = NO_ACTION
          end choose
      case NotModified!
         choose case astatus_new
            case New!, NewModified!, DataModified!
               adw.SetItemStatus(ai_row, 0, adwbuffer, astatus_new)
            case NotModified!
               li_rc = NO_ACTION
         end choose
   end choose
end if

//Validate that the new status is the desired change.
if li_rc = SUCCESS then
   lstatus_changed = adw.GetItemStatus(ai_row, 0, adwbuffer)
   if lstatus_changed <> astatus_new then
      li_rc = FAILURE
      ls_msg = "Row status changed to undesired status"
    end if
end if

//Print error message
if li_rc = FAILURE then
   if IsNull(ls_msg) then
     ls_msg = "[null]"
   end if
   MessageBox("Error - of_SetRowStatus", ls_msg)  
end if

Return li_rc

Here is the overloaded function

//////////////////////////////////////////////////////////////////////////////
//
//   Function: of_SetRowStatus (overloaded function to include buffer)
//
//   Access: Public
//
//   Description: Sets the Rowstatus of the passed row.  It changes the rowstatus
//              of the row and datastore specified in ai_row and adw, to the
//              status specified in astatus_new.
//
//   Arguments: u_dw   adw
//            integer       ai_row
//            dwItemStatus  astatus_new
//
//   Returns:   integer
//
//////////////////////////////////////////////////////////////////////////////
//   Revision History
//
// Date      By   Description/Comments
// --------  ---  -------------------------------------------
// 05/10/06  fjs  Initial Version  (overloaded from original)
// 05/24/06  fjs  Only Primary! and Filter! buffers supported.
//
//////////////////////////////////////////////////////////////////////////////

int li_rc = SUCCESS

li_rc = of_SetRowStatus(adw, ai_row, astatus_new, Primary!)
Return li_rc

About these ads